Griderz Zwicky API

Greetings, 

we have created an API for the Breedables Zwicky, so all of you people with some scripting experience should be able to create items of your own that will help owners of Zwicky.

Anything can be created really, from monitors, to fully functional websites, only your imagination can limit you.
If you make interesting products, please let us know we will make sure Zwicky owners are informed about it!

Breedable Zwicky API

We have in the description of every Zwicky a list of parameters that get updated each time a Zwicky has a status change. 

Here is an example of a Zwicky Description:

Zwicky^2011-05-14^1^<1,1,1>^<1,1,1>^<1,1,1>^0^0^0^0^0^0^1^180^0^1^Ejecta^

All parameters are delimited by the "^" character.
Here is the description of all these parameters:

1-   This field will always be Zwicky, its to determine the breedable your trying to get info from
2-   Birthdate
3-   Gender (1 for male and 0 for female)
4-   Color 1 (Body color)
5-   Color 2 (Skirt color)
6-   Color 3 (Tails color)
7-   Horniness percentage
8-   Gestation (1 for yes, 0 for no)
9-   Gestation percentage
10- Number of fights won
11- Number of fights lost
12- Fight recovery (0 is full recovery)
13- Current age in days
14- Maximum Age 
15- Stasis (0 not in stasis, 1 is in stasis)
16- Breeding (0 all, 1 owner only)
17- Zwicky Breed (ex. Ejecta)

We have also a LSL script you can use in your creations that will do the data scrubbing for you:

//

// Griderz(tm) Zwicky Data Scrubbing Script
//
float RadarRange = 20.0;  // meters
float ScanRate   = 30.0;  // seconds

default
{
    state_entry()
    {
        llSensorRepeat ("", NULL_KEY, SCRIPTED, RadarRange, PI, ScanRate);
    }

    sensor(integer total)
    {
        integer i;
        for(i=0;i<total;++i)
        {
            //find zwicky
            list z=llGetObjectDetails(llDetectedKey(i), ([OBJECT_NAME,OBJECT_DESC,OBJECT_POS]));
            list stats=llParseString2List(llList2String(z,1),["^"],["^"]);
            //if it's a zwicky break down the stats
            if(llList2String(stats,0)=="Zwicky")
            {
                vector position=llList2Vector(z,2);//zwicky position
                string name=llList2String(z,0);//zwicky name
                string uuid=llDetectedKey(i);//zwicky key
                string birthdate=llList2String(stats,1);//birthdate
                string gender=llList2String(stats,2);//gender 1 = male
                string color1=llList2String(stats,3);//color1
                string color2=llList2String(stats,4);//color2
                string color3=llList2String(stats,5);//color3
                string horny=llList2String(stats,6);//horny percentage
                string gestation=llList2String(stats,7);//is it gestating? 1 = yes
                string gestation_percent=llList2String(stats,8);//if so how much?
                string wins=llList2String(stats,9);//fight wins
                string losses=llList2String(stats,10);//fight losses
                string fight_recovery=llList2String(stats,11);//fight recovery zero is full recovery
                string age=llList2String(stats,12);//current age in days
                string max_age=llList2String(stats,13);//maximum age
                string stasis=llList2String(stats,14);//stasis 0 or 1 / 1 = stasis on
                string breeding=llList2String(stats,15);//breeding 0 or 1 / 1 = owner only
                string breed=llList2String(stats,16);//Zwicky Breed
                llOwnerSay((string)position+"|"+name+"|"+uuid+"|"+birthdate+"|"+gender+"|"+color1+"|"+color2+"|"+color3+"|"
+horny+"|"+gestation+"|"+gestation_percent+"|"+wins+"|"+losses+"|"+fight_recovery+"|"+age+"|"+max_age+"|"
+stasis+"|"+breeding+"|"+breed);
            }
        }
    }
}

Statistics

Zwicky In-World: 8843
Zwicky Male In-World: 1356
Zwicky Female In-World: 7487